CHAIN vs SETLL - was SQL Existence Check

["Nathan M. Andelin" <nandelin@xxxxxxxxxxxxxxxxxxx>]

> From: "DeLong, Eric"
> Better be careful..... You're not using any of the fields in the
> read record format, so I *THINK* the compiler speeds up the
> program by not processing unused fields.

Apparently correct.  I added some field references (after the CHAIN loop)
which negatively impacted the performance of the CHAIN.  In this example,
CHAIN takes is 20% more time than SETLL.

     Ftestiol   IF   E           K DISK

     D myKey           S             12A   Dim(10000)
     D i               S             10I 0
     D Now             S               Z
     D Then            S               Z
     D Secs            S             10I 0
     D myNumber        S             10I 0
     D myString        S            128A   Varying

      *-----------------------------------------------------------------

     C                   For       i = 1 to 10000
     C                   Read      testior
     C                   Eval      myKey(i) = tikey
     C                   EndFor

      *-----------------------------------------------------------------

     C                   Time                    Then
     C                   For       i = 1 to 10000
     C     myKey(i)      Setll     testiol                                70
     C                   EndFor

      *-----------------------------------------------------------------

     C                   Time                    Now
     C     Now           Subdur    Then          Secs:*MS
     C     Secs          Dsply

      *-----------------------------------------------------------------

     C                   Time                    Then
     C                   For       i = 1 to 10000
     C     myKey(i)      Chain     testior                            70
     C                   EndFor

      *-----------------------------------------------------------------

     C                   Time                    Now
     C     Now           Subdur    Then          Secs:*MS
     C     Secs          Dsply

      *-----------------------------------------------------------------

     C                   Eval      myNumber = tifld1
     C                   Eval      myNumber = tifld2
     C                   Eval      myNumber = tifld3
     C                   Eval      myNumber = tifld4
     C                   Eval      myNumber = tifld5

     C                   Eval      myString = tifld6
     C                   Eval      myString = tifld7
     C                   Eval      myString = tifld8
     C                   Eval      myString = tifld9
     C                   Eval      myString = tiflda
     C                   Eval      myString = tifldb
     C                   Eval      myString = tifldc
     C                   Eval      myString = tifldd
     C                   Eval      myString = tiflde
     C                   Eval      myString = tifldf
     C                   Eval      myString = tifldg

     C                   SetOn                                        LR
     C                   Return

Nathan M. Andelin
www.relational-data.com