RE: how to get the IP from an interactive session

["Westdorp, Tom" <tom.westdorp@xxxxxxxxxxxxxxxxxx>]

From the August News/400 article:
- - - - - - - - - - - - - - - - - - - - - - - -
RTVIPADDRC:

             PGM        PARM(&IPADDR)

             DCL        VAR(&RCVVAR) TYPE(*CHAR) LEN(892)

             DCL        VAR(&RCVVARLEN) TYPE(*CHAR) LEN(4) +

                          VALUE(X'0000037C')

             DCL        VAR(&FORMAT) TYPE(*CHAR) LEN(8) +

                          VALUE('DEVD0600')

             DCL        VAR(&DEVD) TYPE(*CHAR) LEN(10)

             DCL        VAR(&APIERROR) TYPE(*CHAR) LEN(8) +

                          VALUE(X'0000000000000000')

             DCL        VAR(&IPADDR) TYPE(*CHAR) LEN(15)

             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)

             DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(256)

             DCL        VAR(&MSGF) TYPE(*CHAR) LEN(10)

             DCL        VAR(&MSGFLIB) TYPE(*CHAR) LEN(10)

             MONMSG     MSGID(CPF0000 MCH0000) EXEC(GOTO CMDLBL(ERROR))

 

             RTVJOBA    JOB(&DEVD)

 

             CALL       PGM(QDCRDEVD) PARM(&RCVVAR &RCVVARLEN +

                          &FORMAT &DEVD &APIERROR)

 

             CHGVAR     VAR(&IPADDR) VALUE(%SST(&RCVVAR 878 15))

 

             RETURN

 

Error:

             RCVMSG     MSGTYPE(*EXCP) RMV(*NO) MSGDTA(&MSGDTA) +

                          MSGID(&MSGID) MSGF(&MSGF) MSGFLIB(&MSGFLIB)

                        MONMSG     MSGID(CPF0000 MCH0000)

 

             SNDPGMMSG  MSGID(&MSGID) MSGF(&MSGFLIB/&MSGF) +

                          MSGDTA(&MSGDTA) MSGTYPE(*ESCAPE)

                        MONMSG     MSGID(CPF0000 MCH0000)

 

             ENDPGM   
- - - - - - - - - - - - - - - - - - - - - - - -
RTVIPADDR:

             CMD        PROMPT('Retrieve IP Address')                     
                                                                          
             PARM       KWD(IPADDR) TYPE(*CHAR) LEN(15) RTNVAL(*YES) +    
                          PROMPT('CL Var for IPADDR')

- - - - - - - - - - - - - - - - - - - - - - - -

I haven't tried it yet, but it looked like it would be very useful someday
soon so I created it.

This is available from them at:
http://www.as400network.com/resources/code/

August, 2000 (current) issue.

-----Original Message-----
From: Jodi_Walker@ccmail.columbia.com
[mailto:Jodi_Walker@ccmail.columbia.com]
Sent: Wednesday, August 09, 2000 3:42 PM
To: MIDRANGE-L@midrange.com
Subject: how to get the IP from an interactive session


     Regarding generating PC file formats from AS400 data,
     Jim Franz wrote:
     
     <snip>
     Then I either FTP it to the user (you can capture the IP address they 
     are at during their interactive session from within a clp) 
     <snip>
     
     how do i get the IP address from an interactive session?  i was told 
     that with our network we can't FTP from the 400 to a specific PC (i 
     don't have the specifics so i can't explain in detail). i came up with 
     an alternate method, but would prefer to get rid of it if possible. we 
     use rumba as our emulation software, not CA or CAE.  
     
     if it's an API or command, he name and,if needed, format will suffice. 
      
     thanks
     jw
     
     p.s. any RTFM replies need not bother to waste their time or mine.  i 
     have far too many projects to spend time digging and playing poke and 
     hope when i know someone already has the knowledge that can get me 
     going in the right direction.  i prefer to work smarter, not harder.  
+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to MIDRANGE-L@midrange.com.
| To subscribe to this list send email to MIDRANGE-L-SUB@midrange.com.
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator:
david@midrange.com
+---
+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to MIDRANGE-L@midrange.com.
| To subscribe to this list send email to MIDRANGE-L-SUB@midrange.com.
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---