Re: Ping to test a connection to see if it's alive?

/* Group Dekko Services, LLC                                        */
/* ALL RIGHTS RESERVED.                                             */
/*                                                                  */
/* This program will see if the NOTESFAX Domino server is locked up */
/*                                                                  */
/*                                                                  */
/* Modification log:                                                */
/* 12/31/98 by R.Berendt, CCP   GDS,LLC                             */
/*          Created.                                                */
/*                                                                  */
             PGM

    DCL  &DAY         *CHAR   2  /* Day                              */
    DCL  &DAYOFWEEK   *CHAR   4  /* Day of week ie *MON              */
    DCL  &HOLIDAY     *CHAR   1  /* '0'=No, '1'=Yes                  */
    DCL  &HOUR        *CHAR   2  /* Military format                  */
    DCL  &MONTH       *CHAR   2  /* Month                            */
    DCL  &TRIES       *DEC    2  /*                                  */

LOOP:

    /*                                                                         +
     | Don't check after hours.  We just don't care that bad.                  +
    */
             RTVSYSVAL  SYSVAL(QHOUR) RTNVAR(&HOUR)
             IF         COND((&HOUR < '08') *OR +
                             (&HOUR > '16')) THEN(DO)
             DLYJOB     RSMTIME(080000)
             GOTO       CMDLBL(LOOP)
             ENDDO

    /*                                                                         +
     | Don't check on weekends.                                                +
    */
             RTVSYSVAL  SYSVAL(QDAYOFWEEK) RTNVAR(&DAYOFWEEK)
             IF         COND((&DAYOFWEEK = '*SAT') *OR +
                             (&DAYOFWEEK = '*SUN')) THEN(DO)
             DLYJOB     RSMTIME(080000)
             GOTO       CMDLBL(LOOP)
             ENDDO

    /*                                                                         +
     | Don't check on holidays.                                                +
    */
             RTVSYSVAL  SYSVAL(QDAY) RTNVAR(&DAY)
             RTVSYSVAL  SYSVAL(QMONTH) RTNVAR(&MONTH)
      CALL PGM(HOLIDAY)  PARM( +
      &MONTH           /* Numeric month of year                    */ +
      &DAY             /* Numeric day of month                     */ +
      &DAYOFWEEK       /* Day of week, ie *MON - sysval QDAYOFWEEK */ +
      &HOLIDAY         /* 1=Yes, 0=No                              */ +
      )
             IF         COND(&HOLIDAY='1') THEN(DO)
             DLYJOB     RSMTIME(080000)
             GOTO       CMDLBL(LOOP)
             ENDDO

             CHGVAR     VAR(&TRIES) VALUE(0)

RETRY:
             CHGVAR     VAR(&TRIES) VALUE(&TRIES + 1)
             PING       RMTSYS(NOTESFAX) MSGMODE(*QUIET *ESCAPE)
             MONMSG     MSGID(TCP3210 TCP3202) EXEC(GOTO CMDLBL(ALERT))

DELAY:
             DLYJOB     DLY(900) /* 15 MINUTES */
             GOTO       CMDLBL(LOOP)

ALERT:
             IF         COND(&TRIES < 3) THEN(GOTO CMDLBL(RETRY))
             SNDDST     TYPE(*MSG) TOUSRID((CHRIS DEKKO) (CHRIS +
                          ARCH) (ROB DEKKO) (ROB ARCH) (WATSON +
                          DEKKO)) DSTD(BULLSHIT) MSG('Unable to +
                          ping NOTESFAX')

             GOTO       CMDLBL(DELAY)

END:
             ENDPGM




docfxit@calwest.net on 10/07/99 03:12:35 PM
Please respond to MIDRANGE-L@midrange.com@Internet
To:     MIDRANGE-L@midrange.com@Internet
cc:      
Fax to: 
Subject:        Ping to test a connection to see if it's alive?

Hi,

I was wondering if anyone would be willing to share a CL pgm that does a 
ping to test a connection to see if it's alive?

I sure would appreciate it.

Thank you,

Gary Kuznitz
+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to MIDRANGE-L@midrange.com.
| To subscribe to this list send email to MIDRANGE-L-SUB@midrange.com.
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---


+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to MIDRANGE-L@midrange.com.
| To subscribe to this list send email to MIDRANGE-L-SUB@midrange.com.
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---