Re:FTP Exit point program

[Eric Sundell PMI <esundell@xxxxxxxxxxxxx>]

____________________Reply Separator____________________
Subject:    FTP Exit point program
Author: "Archie Cameron" [SMTP:AGCAMER@mailhost.polarisind.com]
Date:       6/2/99 10:25 AM

Your reply:  That's fairly easy, just create a exit program that restricts
him to whatever directory that you specify, I have a little CL one that I
belted out at one point when we were going to do that, if you want I can
send it to you.

Eric, I would apprecaite a copy of your program.  We have never had to
use them before so we are on new ground.  We are just starting to have
vendors etc. hitting our box and we are pretty nervous.

thanks
Archie G. Cameron
Polaris Industries Inc.



Here you go, one quickie little CL:

A exit program to disallow transfer to any libarary other than TMLIB



/*==================================================================*/
/* To compile:                                                      */
/*                                                                  */
/*           CRTCLPGM   PGM(XXX/NOUP) SRCFILE(XXX/QCLSRC) +        */
/*                      USRPRF(*OWNER)                              */
/*                                                                  */
/* Installation instructions:                                       */
/*   1. Compile program                                             */
/*                                                                  */
/*   2. Change owner of the program to user QSECOFR.                */
/*      Adopted authority allows the program sending                */
/*      to the audit journal                                        */
/*                                                                  */
/*           CHGOBJOWN  OBJ(XXX/NOUP) OBJTYPE(*PGM) +               */
/*                      NEWOWN(QSECOFR)                             */
/*                                                                  */
/*   3. Name the exit program in registration facility              */
/*                                                                  */
/*           ADDEXITPGM EXITPNT(QIBM_QTF_TRANSFER) +                */
/*                      FORMAT(TRAN0100) PGMNBR(1)+                 */
/*                      PGM(XXX/NOUP) +                             */
/*                      TEXT('Limit to specific Libraries')         */
/*                                                                  */
/*   4. Specify the registration facility in the network attribute  */
/*                                                                  */
/*           CHGNETA    PCSACC(*REGFAC)                             */
/*==================================================================*/
PGM        PARM(&RC &STRU)

  DCL        VAR(&RC) TYPE(*CHAR) LEN(1) /* Return: +
               1=allow 0=prevent */
  DCL        VAR(&STRU) TYPE(*CHAR) LEN(80) /* Request +
               description */
  DCL        VAR(&USER) TYPE(*CHAR) LEN(10) /* User +
               profile name */
  DCL        VAR(&APP1) TYPE(*CHAR) LEN(10) /* Requested +
               function */
  DCL        VAR(&APP2) TYPE(*CHAR) LEN(10) /* Sub +
               function */
  DCL        VAR(&TFOBJ) TYPE(*CHAR) LEN(10) /* File +
               Name */
  DCL        VAR(&TFLIB) TYPE(*CHAR) LEN(10) /* +
               Library */
  DCL        VAR(&TFMBR) TYPE(*CHAR) LEN(10) /* Member */
  DCL        VAR(&TFFMT) TYPE(*CHAR) LEN(10) /* Format */

  MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(EXIT))

  CHGVAR     VAR(&RC) VALUE('1') /* Set return code to +
               allow request unless rejected by program  */
  CHGVAR     VAR(&USER) VALUE(%SST(&STRU 1 10)) /* Get +
               user */

  CHGVAR     VAR(&APP2) VALUE(%SST(&STRU 21 10)) /* Get +
               function */
  CHGVAR     VAR(&TFOBJ) VALUE(%SST(&STRU 31 10)) /* Get +
               file */
  CHGVAR     VAR(&TFLIB) VALUE(%SST(&STRU 41 10)) /* Get +
               library */
  CHGVAR     VAR(&TFMBR) VALUE(%SST(&STRU 51 10)) /* Get +
               member */
  CHGVAR     VAR(&TFFMT) VALUE(%SST(&STRU 61 10)) /* Get +
               format */

  /*******************************************/
  /*  Prevent file upload from PC users      */
  /*       except in the TMLIB  library      */
  /*******************************************/
  IF         COND(&APP2 *EQ 'REPLACE') THEN(DO) /* File +
                 upload request */
    IF         COND(&TFLIB *NE 'TMLIB    ') THEN(CHGVAR +
                 VAR(&RC) VALUE('0')) /* Prevent the +
                 request */
  ENDDO

EXIT:
ENDPGM
+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to MIDRANGE-L@midrange.com.
| To subscribe to this list send email to MIDRANGE-L-SUB@midrange.com.
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---