Re: User Exit in COBOL

["R. Bruce Hoffman, Jr." <rbruceh@xxxxxxx>]

Harry D. Angkasa wrote:
> 
> 
>      I still looking for a sample COBOL user exit, any user exit.
>      can anybody help me?

Now, remember, you said ANY.

Following is a COBOL program that simply accepts any FTP connection and
logs it to a file using imbedded SQL.  

Why?  Client needed to know who was using FTP from their machine.  It is
left as an execise for the reader to add other logic to deny access
based on any of the parameters passed in to the exit program.

--- Read da COBOL *ON ---
       PROCESS NOMONOPRC DATETIME.

       Identification division.
        Program-id. "LogFtp".
       Data division.
        Working-storage section.

         01 the-user-id                     pic x(10).
         01 the-ip-address                  pic x(16).

           EXEC SQL include sqlca
             end-exec.

        Linkage section.

         01 p-application-id                pic s9(9) binary.
         01 p-user-id                       pic x(10).
         01 p-user-id-len                   pic s9(9) binary.
         01 p-authentication                pic x(10).
         01 p-authentication-len            pic s9(9) binary.
         01 p-client-ip                     pic x(16).
         01 p-client-ip-len                 pic s9(9) binary.
         01 p-return-code                   pic s9(9) binary.
         01 p-return-user                   pic x(10).
         01 p-return-password               pic x(10).
         01 p-return-current-library        pic x(10).

       Procedure division
           using p-application-id
                 p-user-id
                 p-user-id-len
                 p-authentication
                 p-authentication-len
                 p-client-ip
                 p-client-ip-len
                 p-return-code
                 p-return-user
                 p-return-password
                 p-return-current-library
                 .

       Clean-up-data.

           move spaces
             to the-user-id
                the-ip-address

           move p-user-id(1 : p-user-id-len)
             to the-user-id
           move p-client-ip(1 : p-client-ip-len)
             to the-ip-address
           .

       Log-Access.

           EXEC SQL
             insert
               into FTPLOGFILE
               values(current timestamp,
                      :the-user-id,
                      :the-ip-address)
             end-exec.

           move 1 to p-return-code

           exit program.
           stop run.

--- Read da COBOL *OFF ---

hope this helps.

ta.

-- 
===========================================================
R. Bruce Hoffman, Jr. -- IBM Certified AS/400 Administrator

-- The sum of all human knowledge is a fixed constant.
    It's the population that keeps growing!
+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to MIDRANGE-L@midrange.com.
| To subscribe to this list send email to MIDRANGE-L-SUB@midrange.com.
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---