RE: two RPGLE questions

[Gene Lindsey <GENEL@xxxxxxxxxx>]

After I figured out procedures and service programs and created a little 
timestamp procedure call, Hans tells me I don't need it any more. Does anyone 
need a V3R2 timestamp procedure? I list the source at the end.

Gene
genel@ih2000.net
----------
From:   Hans Boldt[SMTP:hboldt@VNET.IBM.COM]
Sent:   Wednesday, April 23, 1997 7:24 AM
To:     midrange-l@midrange.com
Subject:        re: two RPGLE questions

boothm@earth.goddard.edu wrote:
> In RPGLE:
>
<snip>
>
> 2) How do I move today's date into a field name DateISO, described as
> DATFMT(*ISO)?  I need to do this repeatedly so initializing the value
> isn't an answer.

If you are using V3R7, use the TIME opcode with the date field in the
Result-Field entry.  V3R7  was enhanced to allow date, time, and
timestamp fields with opcode TIME.

Prior to V3R7, you have two steps: 1) Code a 14 digit numeric
field as the result of TIME;  2) MOVE the 14 digit field to field
DateISO.  (Hmmm, this is easier than I first expected!)
<snip>
Cheers!  Hans

Hans Boldt, ILE RPG Development, IBM Toronto Lab, hboldt@vnet.ibm.com
**********************************************************************************************
     HDatFmt(*ISO) NOMAIN                                                       
      *                                                                         
      * TimStmp Create time stamp 
      * this is taken from source presented by Pete Hall 
      * in response to a Midrange-l question. (9/96)                            
                  
      *                                                                         
      *-------------------------------------------------------------------------
      * Include prototype                                                       
      /COPY qincsrc,TimStmpP                                                    
      *                                                                         
     p TimStmp         B                   EXPORT                               
     d TimStmp         PI              Z                                        
      *                                                                         
     d Time_Stamp      s               z                                        
      *                                                                         
     d Mask1           c                   'abcdefghijklmnopq'                  
     d Mask2           c                   'abcd-ef-gh-ij.kl.mn.opq'            
      *                                                                         
     d                 ds                                                       
     d TimeFld                       14  0                                      
     d  TimeIn                        6  0 overlay(TimeFld)                     
     d  DateIn                        8  0 overlay(TimeFld:7)                   
      *                                                                         
     d                 ds                                                       
     d TimeStruct                    26                                         
     d  TM_GREGO                     23    overlay(TimeStruct)                  
     d  uSeconds                      3    inz('000') overlay(TimeStruct:24)    
      *                                                                         
     c                   time                    TimeFld                        
     c                   movel     DateIn        TM_GREGO                       
     c                   move      TimeIn        TM_GREGO                       
      *                                                                         
      * Merge edit mask with date/time for valid time stamp                     
      *                                                                         
     c     Mask1:TM_GREGOxlate     Mask2         TM_GREGO                       
     c                   move      TimeStruct    Time_Stamp                     
      *                                                                         
     c                   return    Time_Stamp                                   
      *                                                                         
     P TimStmp         E                                                        

Standard prototype definition in qincsrc. 
The call is :

d TimeStamp             z
c               eval    TimeStamp=TimStmp()


* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
* This is the Midrange System Mailing List!  To submit a new message,   *
* send your mail to "MIDRANGE-L@midrange.com".  To unsubscribe from     *
* this list send email to MAJORDOMO@midrange.com and specify            *
* 'unsubscribe MIDRANGE-L' in the body of your message.  Questions      *
* should be directed to the list owner / operator: david@midrange.com   *
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *