Re: GENUUID - bound program access

Hello Steve,

Here's a sample:

H Option( *NoSrcStmt )
**
D HxUUID          s             32a
**
D UUID_template   Ds
D  UtBytPrv                     10u 0 Inz( %Size( UUID_template ))
D  UtBytAvl                     10u 0
D                                8a   Inz( *Allx'00' )
D  UUID                         16a
**
D GenUuid         Pr                  ExtProc('_GENUUID')
D  UUID_template                  *   Value
**
D cvthc           Pr              *   ExtProc('cvthc')
D                                 *   Value
D                                 *   Value
D                               10I 0 Value
**
C                   Callp     GenUuid( %Addr( UUID_template ))
**
C                   CallP     cvthc( %Addr( HxUUID )
C                                  : %Addr( UUID )
C                                  : %Size( HxUUID )
C                                  )
**
C                   Return
**

Best regards,
Carsten Flensburg

----- Original Message -----
From: "Steve Richter" <srichter@autocoder.com>
To: "mi mail list" <MI400@midrange.com>
Sent: Thursday, August 15, 2002 6:05 PM
Subject: [MI400] GENUUID - bound program access


> I want to run the GENUUID MI instruction from an rpg ile program. Can
> someone post the rpg code needed to run an MI instruction, via Bound
program
> access ?