Re: color attribute problem

On Mon, 25 Oct 2004, phil wrote:
>
> Oh, btw. I have an AS400 which does support testreq,
> which I could possibly port forward you to if you have a
> routable ip address.  If your interested.
> We can talk about it later.

I created the following DDS and RPG that displays a string with every
possible display attribute.  When I run this under both RUMBA and TN5250,
the attributes look the same -- I don't have Client Access, so I can't
compare to that.

Here's the source:

Member ALLATTRS of file QDDSSRC:

     A                                      DSPSIZ(24 80 *DS3)
     A                                      INDARA
     A          R ALLATTR1S                 SFL
     A            SFLDATA       24   O  2 29
     A          R ALLATTR1C                 SFLCTL(ALLATTR1S)
     A N50                                  SFLDSP
     A N50                                  SFLDSPCTL
     A  50                                  SFLCLR
     A N50                                  SFLEND
     A                                      SFLSIZ(0032)
     A                                      SFLPAG(0022)

Member ALLATTRR4 of file QRPGLESRC:

     H DFTACTGRP(*NO) BNDDIR('QC2LE')

     FALLATTRS  CF   E             WORKSTN SFILE(ALLATTR1S: RRN)
     F                                     INDDS(dsIndic)

     D dsIndic         ds
     D   Clear_Sfl            50     50N

     D Q               C                   ''''

     D                 ds
     D   byte                         1A
     D   val                          3U 0 overlay(byte)

     D toHex           PR                  extproc('cvthc')
     D  output                        2A
     D  input                         1A
     D  output_len                   10I 0 value

     D hexval          s              2A
     D RRN             s              4  0

      /free

       clear_sfl = *on;
       write ALLATTR1C;
       clear_sfl = *off;
       rrn = 0;

       for val = 32 to 62;
           toHex(hexval: byte: 2);

           sfldata = 'x' + Q + hexval + Q + byte + 'DISPLAYS LIKE THIS';
           rrn += 1;

           write ALLATTR1S;
       endfor;


       exfmt ALLATTR1C;
       *inlr = *on;

      /end-free

Compile with:
      CRTDSPF FILE(ALLATTRS) SRCFILE(mylib/QDDSSRC)
      CRTBNDRPG PGM(ALLATTRR4) SRCFILE(mylib/QRPGLESRC)