AW: Using LIKE Operator in SQLRPGLE ?

Hi Rob,

you either have to use a field with varying length or
use the Scalar Function TRIM or RTRIM in your Select-Statement
to cut the trailing *Blanks.
An other solution will be to replace LIKE through the scalar function
POSSTR()

Examples:
D HstName         S             50A   varying
D HstNameFix      S             50A
D DspName         S             50A
 *---------------------------------------------------------
C                   Eval      HstNameFix = '%MyText%'
C/Exec SQL
C+ Declare CsrC0 Cursor for
C+   Select Name1F from Adresse
C+            Where     Name1F Like Trim(:HstNameFix)
C/End-Exec

C/EXEC SQL Open CsrC0
C/END-EXEC

/EXEC SQL Fetch CsrC0 into :DspName
c/END-EXEC

c/EXEC SQL Close CsrC0
C/END-EXEC
C     DspName       Dsply
 *---------------------------------------------------------
C                   Eval      HstName = '%OtherText%'

C/Exec SQL
C+ Declare CsrC1 Cursor for
C+   Select Name1F from Adresse
C+            Where     Name1F Like :HstName
C/End-Exec

c/EXEC SQL Open CsrC1
C/END-EXEC

c/EXEC SQL Fetch CsrC1 into :DspName
c/END-EXEC

c/EXEC SQL Close CsrC1
C/END-EXEC
C     DspName       Dsply
 *----------------------------------------------------------
C                   eval      HstName = 'NextText'

C/Exec SQL
C+ Declare CsrC2 Cursor for
C+   Select Name1F from Adresse
C+            Where     PosStr (Name1F, :HstName) > 0
C/End-Exec

c/EXEC SQL Open CsrC2
C/END-EXEC

c/EXEC SQL Fetch CsrC2 into :DspName
c/END-EXEC

c/EXEC SQL Close CsrC2
C/END-EXEC
C     DspName       Dsply

C                   Eval      *InLR = *On

Birgitta

-----Ursprungliche Nachricht-----
Von: rpg400-l-bounces@xxxxxxxxxxxx
[mailto:rpg400-l-bounces@xxxxxxxxxxxx]Im Auftrag von rob@xxxxxxxxx
Gesendet: Mittwoch, 16. Februar 2005 22:19
An: RPG programming on the AS400 / iSeries
Betreff: RE: Using LIKE Operator in SQLRPGLE ?


That doesn't seem to work.

Rob Berendt
--
Group Dekko Services, LLC
Dept 01.073
PO Box 2000
Dock 108
6928N 400E
Kendallville, IN 46755
http://www.dekko.com





"Martin, Steve (MAN-Golden)" <Steve.Martin@xxxxxxx>
Sent by: rpg400-l-bounces@xxxxxxxxxxxx
02/16/2005 03:48 PM
Please respond to
RPG programming on the AS400 / iSeries <rpg400-l@xxxxxxxxxxxx>


To
"'RPG programming on the AS400 / iSeries'" <rpg400-l@xxxxxxxxxxxx>
cc

Subject
RE: Using LIKE Operator in SQLRPGLE ?






Can you use an EVAL statement to append the '%' to CID just before the
SQL?

-----Original Message-----
From: rpg400-l-bounces@xxxxxxxxxxxx
[mailto:rpg400-l-bounces@xxxxxxxxxxxx]On Behalf Of Luqman
Sent: Wednesday, February 16, 2005 1:30 PM
To: rpg400-l@xxxxxxxxxxxx
Subject: Using LIKE Operator in SQLRPGLE ?


How can I use LIKE Operator in SQLRPGLE ?

I tried following but its giving error.

CID is a string variable.

C/ EXEC SQL
C+ SELECT * FROM INVOICE WHERE CUSTID LIKE :CID ||'%'
C/END EXEC

Best Regards,

Luqman





--
This is the RPG programming on the AS400 / iSeries (RPG400-L) mailing list
To post a message email: RPG400-L@xxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: http://lists.midrange.com/mailman/listinfo/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives
at http://archive.midrange.com/rpg400-l.
--
This is the RPG programming on the AS400 / iSeries (RPG400-L) mailing list
To post a message email: RPG400-L@xxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: http://lists.midrange.com/mailman/listinfo/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives
at http://archive.midrange.com/rpg400-l.


--
This is the RPG programming on the AS400 / iSeries (RPG400-L) mailing list
To post a message email: RPG400-L@xxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: http://lists.midrange.com/mailman/listinfo/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives
at http://archive.midrange.com/rpg400-l.