RE: QWCRSVAL API

I use it to get the serial number as follows:

D QWCRSVAL        PR                  ExtPgm('QWCRSVAL')   
D  p_Rcvr                             Like(w_Rcvr)         
D  p_RcvrLngth                        Like(w_RcvrLngth)    
D  p_NbrToRtv                         Like(w_NbrToRtv)     
D  p_SysVal                           Like(w_SysVal)       
D  p_Error                            Like(DS_APIError)    

 ************************************************************************** 
 * #RtvSrlNbr - Retrieve the system Serial Number                         * 
 ************************************************************************** 
P #RtvSrlNbr      B                   Export                                
D                 PI             8a                                         
                                                                            
 * Work Fields used by Procedure                                            
D  w_SrlNbr       S              8                                          
D  w_Rcvr         S             36a                                         
D  w_RcvrLngth    S             10i 0 inz(%len(w_Rcvr))                     
D  w_NbrToRtv     S             10i 0 inz(1)                                
D  w_SysVal       S             10a   inz('QSRLNBR')                        
                                                                            
 * Prototypes for calls                                                     
D QWCRSVAL        PR                  ExtPgm('QWCRSVAL')         
D  p_Rcvr                             Like(w_Rcvr)               
D  p_RcvrLngth                        Like(w_RcvrLngth)          
D  p_NbrToRtv                         Like(w_NbrToRtv)           
D  p_SysVal                           Like(w_SysVal)             
D  p_Error                            Like(DS_APIError)          
                                                                 
D DS_SysValTbl    DS                                             
D  d_ValsRtn                    10i 0                            
D  d_Offset                     10i 0                            
D  D_Align                       4a                              
D  d_SysVal                     10a                              
D  d_ValType                     1a                              
D  d_InfoSts                     1a                              
D  d_DtaLngth                   10i 0                            
D  d_Data                       10a                              
                                                                 
C                   Reset                   DS_APIError          
                                                                      
C                   CallP     QWCRSVAL(w_Rcvr :                       
C                                      w_RcvrLngth :                  
C                                      w_NbrToRtv :                   
C                                      w_SysVal :                     
C                                      DS_APIError )                  
C                   Eval      DS_SysValTbl = w_Rcvr                   
C                   Eval      w_SrlNbr = %subst(d_Data:1:d_DtaLngth)  
C                   Return    w_SrlNbr                                
P #RtvSrlNbr      E                                                   



-----Original Message-----
From: Mike Silvers [mailto:msilvers@hbs-inc.com]
Sent: Thursday, November 16, 2000 3:59 AM
To: RPG400-L
Subject: QWCRSVAL API


Has anyone used the QWCRSVAL API to retrieve system values?  I am trying to
use it and it is a bit confusing..  Any examples/help would be appreciated.

Thanks

Mike


================================

Mike Silvers
AS/400 Senior Programmer/Analyst
AS/400 IBM Certified Expert
Hainey Business Systems
8 E. Canal St
Dover, PA 17315
Branch Office:  (410) 397-8739
Phone:  (800) 932-3380
Fax:  (717) 292-9474
Web: http:\\www.hbs-inc.com
________________________________
Providing E-Commerce, EDI, AS/400
Development and related services
nationwide.
================================

+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator:
david@midrange.com
+---
+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---