Re: simulated SETLL with SQL

Look at the PREPARE statement.

     D HostVar         S            200
     D SortCol         S             10A
     D fileds        E DS                  extname(aaakey)

     C                   eval      SortCol='loc'
     C                   exsr      test
     C                   eval      SortCol='comp'
     C                   exsr      test

     C                   eval      *inlr=*on
      *********************************************************

     C     test          BegSr

     C                   eval      HostVar='Select loc, comp, coname ' +
     C                                      'from aaakey ' +
     C                                      'order by '  + SortCol +
     C                                      'for fetch only'

     C/EXEC SQL
     C+ prepare stmt from :hostvar
     C/END-EXEC

     C/EXEC SQL
     C+ Declare C1 cursor for stmt
     C/END-EXEC

     C/EXEC SQL
     C+ Open C1
     C/END-EXEC

     C/EXEC SQL
     C+ Fetch C1 into :loc, :comp, :coname
     C/END-EXEC

     C                   dow       sqlcod=*zeros

     C* load subfile record

     C/EXEC SQL
     C+ Fetch C1 into :loc, :comp, :coname
     C/END-EXEC
     C                   enddo

     C/EXEC SQL
     C+ Close C1
     C/END-EXEC

     C                   EndSr




mwalter@netrax.net on 03/20/2000 03:26:13 PM
Please respond to RPG400-L@midrange.com@Internet
To:     rpg400-l@midrange.com@Internet
cc:      
Fax to: 
Subject:        simulated SETLL with SQL

Hello all,

Welcome back all who attended COMMON. I hope everyone found the conference 
stimulating.

I am attempting, for lack of a better term, a "work with" screen in which I 
want to dynamically change the sort order of data in a subfile. I have a 
window with a single choice field to select the sort order. I am doing all 
of the record selection with SQL. (declaring a cursor, opening the cursor, 
fetching the rows into the subfile, closing the cursor)

My problem is the original screen (which had only one sort) had a position 
to field. I need to know how to simulate a SETLL and READ with SQL. I would 
also like to know if I can place the sort field into a host variable. 
Currently I declare and utilize a different cursor for each possible sort.

thanks in advance

Mark Walter
+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---


+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---