AW: RNF5347E An assignment operator is expected with the EVAL operation.

The SET OPTION - statement must be physically the FIRST SQL Statement in
your source code.
Insert your SET OPTION statement as 1st C-Statement. In NoMain procedures it
can be inserted before the 1st P-Statement.

Mit freundlichen Grüßen / Best regards

Birgitta Hauser

"Shoot for the moon, even if you miss, you'll land among the stars." (Les
Brown)
"If you think education is expensive, try ignorance." (Derek Bok)
"What is worse than training your staff and losing them? Not training them
and keeping them!"


-----Ursprüngliche Nachricht-----
Von: rpg400-l-bounces@xxxxxxxxxxxx [mailto:rpg400-l-bounces@xxxxxxxxxxxx] Im
Auftrag von rob@xxxxxxxxx
Gesendet: Wednesday, 10. February 2010 17:59
An: RPG programming on the IBM i/System i
Betreff: SQL: RNF5347E An assignment operator is expected with the EVAL
operation.

exec sql update rob/a1sqlf set mykey=mykey*1
where current of C1;
Gets
RNF5347E An assignment operator is expected with the EVAL operation.

No tgtrls specified. Using CRTSQLRPGI.


Complete program follows:

H ActGrp(*CALLER)
H DftActGrp(*NO)

D OpenCursor PR n
D FetchCursor PR n
D CloseCursor PR n

D mykey s 5i 0
D Mychar s 5a

/free
*inlr=*on;
if not OpenCursor();
// perform error routine to alert the troops
// ...
Else;
Dow FetchCursor();
// putting the fetchcursor on the do loop allows the user of
// iter, and thus iter will not perform an infinite loop
// normal processing here...
exec sql update rob/a1sqlf set mykey=mykey*1
where current of C1;
EndDo;
CloseCursor();
EndIf;
return;
/end-free

P OpenCursor B
D OpenCursor PI like(ReturnVar)
D ReturnVar s n

/free
EXEC SQL
Set Option
Naming = *Sys,
Commit = *None,
UsrPrf = *User,
DynUsrPrf = *User,
Datfmt = *iso,
CloSqlCsr = *EndMod,
COMPILEOPT='DBGVIEW(*LIST)';

EXEC SQL
Declare C1 cursor for
Select mykey,
mydata
from rob/a1sqlf;

EXEC SQL
Open C1;

Select;
When SqlStt='00000';
return *on;
Other;
return *off;
EndSl;
/end-free
P OpenCursor E

/eject
P FetchCursor B
D FetchCursor PI like(ReturnVar)
D ReturnVar s n
/free
EXEC SQL
Fetch C1 into :mykey, :myChar;
Select;
When sqlstt='00000';
// row was received, normal
ReturnVar=*on;
When sqlstt='02000';
// same as %eof, sooner or later this is normal
ReturnVar=*off;
Other;
// alert the troops!
ReturnVar=*off;
EndSl;
return ReturnVar;
/end-free
P FetchCursor E

/eject
P CloseCursor B
D CloseCursor PI like(ReturnVar)
D ReturnVar s n
/free
EXEC SQL
Close C1;
Select;
When sqlstt='00000';
// cursor was closed, normal
ReturnVar=*on;
Other;
// alert the troops!
ReturnVar=*off;
EndSl;
return ReturnVar;
/end-free
P CloseCursor E

Rob Berendt