Odp: Re: Feedback ds for CEEDAYS API

Thank you Carsten 
cvthc - it was what I needed

Regards 
Marcin Sagan

>>> "Carsten Flensburg" <flensburg@novasol.dk> 11/27 4:10  >>>
Hello Marcin,

Here you go:
     **--------------------------------------------------------------------**
     **                                                                    **
     ** Compile options required:                                          **
     **             DftActGrp( *NO )   +                                   **
     **             ActGrp( QILE )     +                                   **
     **             BndDir( QC2LE )                                        **
     **                                                                    **
     **-- Parameters:  -------------------------------------------------------**
     D DtLil           s             10i 0
     **
     D MsgId           s              7a
     D MsgHex          s              4a
     **
     D Feedback        Ds
     D  FB                           10u 0
     D   MsgSev                       5u 0 Overlay( FB: 1 )
     D   MsgNo                        5u 0 Overlay( FB: 3 )
     D  Bits                          1a
     **  Case   :2
     **  Sev    :3
     **  Ctl    :3
     D  Facility_id                   3a
     D  IS_Info                      10u 0
     **-- Date function:  ----------------------------------------------------**
     D CeeDays         Pr                  ExtProc( 'CEEDAYS' )  OpDesc
     D  CdDatChr                     32a   Const  Options( *VarSize )
     D  CdDatPic                     32a   Const  Options( *VarSize )
     D  CdLilDat                     10i 0
     D  CdFc                         12a   Options( *Omit )
     **
     D cvthc           Pr              *   ExtProc( 'cvthc' )
     D                                 *   Value
     D                                 *   Value
     D                               10i 0 Value
     **-- Convert:  ----------------------------------------------------------**
     **
     C                   CallP     CeeDays( '20001127'
     C                                    : 'YYYYDDMM'
     C                                    : DtLil
     C                                    : Feedback
     C                                    )
     **
     C                   If        FB    > *Zero
     **
     C                   CallP     cvthc( %Addr( MsgHex )
     C                                  : %Addr( MsgNo )
     C                                  : %Size( MsgHex )
     C                                  )
     C                   Eval      MsgId = Facility_Id + MsgHex
     C                   EndIf
     **
     C                   Return
     **

Best regards,
Carsten

                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                               !
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                               !
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                               !
                                                                                
                                        
+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---