RE: SYSTEM SPACE

I wrote the following - it's submitted to QCTL in QSRTUP. This may be of
some help for %ASP used and a couple of other issues.

          PGM
             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)
             DCL        VAR(&MSG3) TYPE(*CHAR) LEN(3)
             DCL        VAR(&RTNTYPE) TYPE(*CHAR) LEN(2)
             DCL        VAR(&KEYVAR) TYPE(*CHAR) LEN(4)
             DCL        VAR(&MSGIN) TYPE(*CHAR) LEN(132)
             CHGMSGQ    MSGQ(QSYS/QSYSOPR) RESET(*YES)
 BEGIN:      RCVMSG     MSGQ(QSYS/QSYSOPR) MSGTYPE(*INFO) +
                          MSGKEY(*NONE) WAIT(0) RMV(*NO) +
                          MSG(&MSGIN) MSGID(&MSGID) RTNTYPE(&RTNTYPE)
             MONMSG     MSGID(CPF2451) EXEC(GOTO CMDLBL(M2451))
             MONMSG     MSGID(CPF2410) EXEC(GOTO CMDLBL(DONE))
             GOTO       CMDLBL(MSG)
 AGAIN:      CHGMSGQ    MSGQ(QSYS/QSYSOPR) RESET(*NO)
             MONMSG     MSGID(CPF2451) EXEC(GOTO CMDLBL(M2451))
             MONMSG     MSGID(CPF2410) EXEC(GOTO CMDLBL(DONE))
             RCVMSG     MSGQ(QSYS/QSYSOPR) MSGTYPE(*INFO) +
                          WAIT(0) RMV(*NO) +
                          MSG(&MSGIN) MSGID(&MSGID) RTNTYPE(&RTNTYPE)
             MONMSG     MSGID(CPF2451) EXEC(GOTO CMDLBL(DONE))
             MONMSG     MSGID(CPF2410) EXEC(GOTO CMDLBL(DONE))
 MSG:        IF         COND(&MSGID = 'CPI1479') THEN(GOTO +
                          CMDLBL(M1479))
             IF         COND(&MSGID = 'CPF2526') THEN(GOTO +
                          CMDLBL(M2526))
             IF         COND(&MSGID = 'CPF1393') THEN(GOTO +
                          CMDLBL(M1393))
             IF         COND(&MSGID = 'CPF0907') THEN(GOTO +
                          CMDLBL(M0907))
             IF         COND(&MSGID = 'CPI1158') THEN(GOTO +
                          CMDLBL(M1158))
             CHGVAR     VAR(&MSG3) VALUE(%SUBSTRING(&MSGID 1 3))
             IF COND(&MSG3 = 'CPP') THEN(GOTO CMDLBL(MCPP))
             GOTO       CMDLBL(DONE)
 M1479:      SNDDST     TYPE(*LMSG) +
                          TOINTNET(('xxx@xxxxxxx')) +
                          DSTD('CPI1479 - Interactive activity') +
                          LONGMSG('CPI1479 - Interactive activity +
                          approaching capacity of installed feature.')
             GOTO       CMDLBL(DONE)
 M2526:      SNDDST     TYPE(*LMSG) +
                          TOINTNET(('xxx@xxxxxxx')) +
                          DSTD('CPF2526-Job message queue cannot be +
                          extended') LONGMSG(&MSGIN)
             GOTO       CMDLBL(DONE)
 M1393:      SNDDST     TYPE(*LMSG) +
                          TOINTNET(('xxx@xxxxxxx')) +
                          DSTD('CPF1393 - Disabled user profile.') +
                          LONGMSG(&MSGIN)
             GOTO       CMDLBL(DONE)
 M0907:      SNDDST     TYPE(*LMSG) +
                          TOINTNET(('xxx@xxxxxxx')) +
                          DSTD('CPF0907-Serious storage condition +
                          may exist.') LONGMSG(&MSGIN)
             GOTO       CMDLBL(DONE)
 M1158:      SNDDST     TYPE(*LMSG) +
                          TOINTNET(('xxx@xxxxxxx')) +
                          DSTD('CPI1158-Aux storage exceeds system +
                          limits') LONGMSG(&MSGIN)
             GOTO       CMDLBL(DONE)
 MCPP:       SNDDST     TYPE(*LMSG) +
                          TOINTNET(('xxx@xxxxxxx')) +
                          DSTD('CPP*-See message details') +
                          LONGMSG(&MSGIN)
             GOTO       CMDLBL(DONE)
 M2451:      SNDDST     TYPE(*LMSG) +
                          TOINTNET(('xxx@xxxxxxx')) +
                          LONGMSG('CPI2451 - QSYSOPR MSGQ LOCKED.')
             DLYJOB     DLY(120)
             GOTO       CMDLBL(AGAIN)
 DONE:       DLYJOB     DLY(120)
             GOTO       CMDLBL(AGAIN)
             ENDPGM

-----Original Message-----
From: midrange-l-bounces@xxxxxxxxxxxx
[mailto:midrange-l-bounces@xxxxxxxxxxxx] On Behalf Of Carey Jeff -
jcarey
Sent: Monday, August 22, 2005 8:48 AM
To: Midrange Systems Technical Discussion; Midrange Systems Technical
Discussion (E-mail)
Subject: RE: SYSTEM SPACE


WRKSYSSTS gives you an idea of space used in the system ASP (systems
often have only one pool of disk, the system ASP).  RTVDSKINF (which
takes a while to run) followed by PRTDSKINF is the most complete listing
of space used and available.
 
To see the size of each disk., use WRKDSKSTS.  Note that if the disk is
protected by RAID (as it often is on iSeries), the usable space after
the effects of RAID striping is shown.  Generally, you can just round up
to get the "real" disk size (4GB, 8GB, 17GB, 35GB and 70GB are the ones
I can think of).
 
Jeff

________________________________

From: midrange-l-bounces@xxxxxxxxxxxx on behalf of Dwayne Allison
Sent: Mon 8/22/2005 8:27 AM
To: Midrange Systems Technical Discussion (E-mail)
Subject: SYSTEM SPACE



Good Morning,


How do I check the system space and hard drive size on the AS/400?

--
This is the Midrange Systems Technical Discussion (MIDRANGE-L) mailing
list
To post a message email: MIDRANGE-L@xxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: http://lists.midrange.com/mailman/listinfo/midrange-l
or email: MIDRANGE-L-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives
at http://archive.midrange.com/midrange-l.


************************************************************************
**
The information contained in this communication is confidential, is
intended only for the use of the recipient named above, and may be
legally
privileged.

If the reader of this message is not the intended recipient, you are
hereby notified that any dissemination, distribution or copying of this
communication is strictly prohibited.

If you have received this communication in error, please resend this
communication to the sender and delete the original message or any copy
of it from your computer system.

Thank You.
************************************************************************
**