Re: Old qstrup -- MIDRANGE-L

× The internal search function is temporarily non-functional. The current search engine is no longer viable and we are researching alternatives.
As a stop gap measure, we are using Google's custom search engine service.
If you know of an easy to use, open source, search engine ... please contact support@midrange.com.

> I have a old qstrup, in a new i520.
> Do i need the strtcpsrv....?

You shouldn't need these if the servers are flagged with Autostart Server
*YES in their attributes.  

> Anyone who have a orginal qstrup from IBM for V5M3M0?    

Unless you've blown it away, you should be able to RTVCLSRC on QSYS/QSTRUP.
In case you have, here it is:


     PGM                                                                 
     DCL VAR(&STRWTRS) TYPE(*CHAR) LEN(1)                                
     DCL VAR(&CTLSBSD) TYPE(*CHAR) LEN(20)                               
     DCL VAR(&CPYR) TYPE(*CHAR) LEN(90) VALUE('5722-SS1 (C) COPYRIGHT-   
 IBM CORP 1980, 2000. LICENSED MATERIAL - PROGRAM PROPERTY OF IBM')      
     QSYS/STRSBS SBSD(QSERVER)                                           
     MONMSG MSGID(CPF0000)                                               
     QSYS/STRSBS SBSD(QUSRWRK)                                           
     MONMSG MSGID(CPF0000)                                               
     QSYS/RLSJOBQ JOBQ(QGPL/QS36MRT)                                     
     MONMSG MSGID(CPF0000)                                               
     QSYS/RLSJOBQ JOBQ(QGPL/QS36EVOKE)                                   
     MONMSG MSGID(CPF0000)                                               
     QSYS/STRCLNUP                                                       
     MONMSG MSGID(CPF0000)                                               
     QSYS/RTVSYSVAL SYSVAL(QCTLSBSD) RTNVAR(&CTLSBSD)                    
     IF COND((&CTLSBSD *NE 'QCTL      QSYS      ') *AND (&CTLSBSD *NE-   
 'QCTL      QGPL      ')) THEN(GOTO CMDLBL(DONE))                        
     QSYS/STRSBS SBSD(QINTER)                                            
     MONMSG MSGID(CPF0000)                                 
     QSYS/STRSBS SBSD(QBATCH)                              
     MONMSG MSGID(CPF0000)                                 
     QSYS/STRSBS SBSD(QCMN)                                
     MONMSG MSGID(CPF0000)                                 
DONE:                                                      
     QSYS/STRSBS SBSD(QSPL)                                
     MONMSG MSGID(CPF0000)                                 
     QSYS/RTVSYSVAL SYSVAL(QSTRPRTWTR) RTNVAR(&STRWTRS)    
     IF COND(&STRWTRS = '0') THEN(GOTO CMDLBL(NOWTRS))     
     CALL PGM(QSYS/QWCSWTRS)                               
     MONMSG MSGID(CPF0000)                                 
NOWTRS:                                                    
     RETURN                                                
     CHGVAR VAR(&CPYR) VALUE(&CPYR)                        
     ENDPGM

This mailing list archive is Copyright 1997-2024 by midrange.com and David Gibbs as a compilation work. Use of the archive is restricted to research of a business or technical nature. Any other uses are prohibited. Full details are available on our policy page. If you have questions about this, please contact [javascript protected email address].

Operating expenses for this site are earned using the Amazon Associate program and Google Adsense.