Re: query definiton

the rtvqmqry command can do that, into a source file.
the following finds all the queries in a library list
and rtvs the query source, making it avail to scan.
hth
jim

            PGM        /* rtv qm qry source for all queries in +
                          production libraries */
             DCL        VAR(&MSG) TYPE(*CHAR) LEN(70)
             DCLF       FILE(QADSPOBJ)
             MONMSG     MSGID(CPF0000) /* global monitor */

             DSPOBJD    OBJ(*USRLIBL/*ALL) OBJTYPE(*QRYDFN) +
                          OUTPUT(*OUTFILE) OUTFILE(QTEMP/ZDSPOBJD) +
                          OUTMBR(*FIRST *REPLACE)
             OVRDBF     FILE(QADSPOBJ) TOFILE(QTEMP/ZDSPOBJD)
 $READ:      RCVF
             MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL($END))
/* IF A QRY, RTV SOURCE */
             IF         COND(&ODOBTP *EQ '*QRYDFN') THEN(DO)

/* IF NOT A SOURCE PF  , CREATE IT */
             CHKOBJ     OBJ(&ODLBNM/QRTVQRY) OBJTYPE(*FILE)
             MONMSG     MSGID(CPF9801) EXEC(DO)
             CRTSRCPF   FILE(&ODLBNM/QRTVQRY) TEXT('RTVQMQRY src')
            ENDDO
            RTVQMQRY   QMQRY(&ODLBNM/&ODOBNM) +
                         SRCFILE(&ODLBNM/QRTVQRY) SRCMBR(*QMQRY) +
                         ALWQRYDFN(*YES)

            ENDDO
$NEXT:      GOTO       CMDLBL($READ)
$DISPLAY:

$END:       ENDPGM


----- Original Message ----- 
From: "Hatzenbeler, Tim" <thatzenbeler@xxxxxxxxxxxxx>
To: "'Midrange Systems Technical Discussion'" <midrange-l@xxxxxxxxxxxx>
Sent: Wednesday, April 28, 2004 12:21 PM
Subject: query definiton


> Is there a way, with QUERY/400 to extract the details of the report... For
> example,  what files were joined, what fields were created or defined, and
> the record selection...
>
> in a print or outfile?
>
> Thanks, tim
>
> This e-mail message, including any attachments, is for the sole use of the
> intended recipient(s) and may contain confidential or privileged
> information.  Any unauthorized review, use, disclosure or distribution is
> prohibited.  If you are not the intended recipient, please contact the
> sender by reply e-mail and destroy the message.
> _______________________________________________
> This is the Midrange Systems Technical Discussion (MIDRANGE-L) mailing
list
> To post a message email: MIDRANGE-L@xxxxxxxxxxxx
> To subscribe, unsubscribe, or change list options,
> visit: http://lists.midrange.com/mailman/listinfo/midrange-l
> or email: MIDRANGE-L-request@xxxxxxxxxxxx
> Before posting, please take a moment to review the archives
> at http://archive.midrange.com/midrange-l.
>
>